kentcowgill.org/blog

It's been a while since I've posted anything technical. Possibly, upon reflection, because it seems that there's very little at my current job that sticks in my craw enough to feel the need to vent about it on my blog.

So instead I'll talk about an itch of mine I recently felt the need to scratch.

My listing of tags to the right was pretty bad. I came up with an algorithm to show tags with higher post counts in a bigger font than tags with lower post counts. But it was pretty sophomoric. In fact, I poked fun of my algorithm in talk I gave about photo processing in perl at this years YAPC::NA where I made a comment about this algorithm as a "highly complicated and sophisticated formula derived by minutes and minutes of trial and error".

I reproduce it here for your amusement:

<span style="font-size: [% ( tag.num + 80 ) / 8 %]px">

But I had a flaw.

Every time I noticed some of the tag fonts get too large due to me posting more and more posts with tags, I had to manually tweak the formula to give the font sizes a gentler slope - so the larger fonts didn't get too large.

Google to the rescue. I googled for tag cloud font size algorithm and found a font size variation algorithm that looked promising.

All I needed to do was use min and max from List::Util, and add this code to the backend before sending my data off to Template:

use List::Util qw/min max/;

my $tag_min = min map { $_->{ num } } @tags;
my $tag_max = max map { $_->{ num } } @tags;

for my $tag_row( @tags ){
  $tag_row->{ fontsize } = get_fontsize(
                                          $tag_row->{ num },
                                          $tag_min,
                                          $tag_max,
                                          $MIN_FONTSIZE,
                                          $MAX_FONTSIZE,
                                       );
}

... given that @tags is an array of hashrefs containing tags and their respective counts.

What's the get_fontsize look like?

{
  my %font_cache;
  sub get_fontsize {
    my( $count, $min_count, $max_count, $min_size, $max_size ) = @_;

    return $font_cache{ $count } if $font_cache{ $count };

    my $weight = ( log( $count ) - log( $min_count ) )
               / ( log( $max_count ) - log( $min_count ) );

    $font_cache{ $count } = $min_size
                          + round( ( $max_size - $min_size )
                                   * $weight );
  }
}

Which leaves a much more sensible hunk of code in the template file:

<span class="tags" style="font-size: [% tag.fontsize %]px">